使用 VBS 脚本一键关闭/开启 Windows 更新功能

这个东西缙哥哥在52破解看到过，但是懒得去试，结果前不久缙哥哥居然遇到了一个清空，就是微软将我的笔记本电脑升级了，并提示我升级到 Windows 11（因为《入手惠普HP战66六代2023锐龙版15.6寸轻薄笔记本》后改安装 Windows 10 专业版），被我拒绝了，刚好今天看狗哥也分享了这个，所以记录一下，并分享给大家。

该VBS脚本的实现原理是提供建议对话框，然后通过用户的选择，执行对应的修改注册表操作。所以不要怕会搞坏，你能把系统搞崩都搞不坏 Windows 更新。

VBS 脚本代码

Const usosvc_reg = "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\usosvc"
Set fso = createobject("scripting.filesystemobject")
Set shell = createobject("wscript.shell")
curdir = fso.getparentfoldername(wscript.scriptfullname)
If wscript.arguments.count = 0 Then
    Set sh = createobject("shell.application")
    sh.shellexecute wscript.fullname,"""" & wscript.scriptfullname & """ -admin",,"runas"
ElseIf wscript.arguments.count = 1 And wscript.arguments(0) = "-admin" Then
    run
Else
    msgbox "脚本启动参数错误!"
End If
Sub Run()
    Do
        ret = inputbox("1. 禁止 Win10 自动更新;" & vbcrlf & _
		"2. 恢复 Win10 自动更新;" & vbcrlf & _
        vbcrlf & _
        "请输入序号:","管理 Win10 自动更新 v3","1")
        Select Case ret
        Case "1"
            retnum = shell.run("sc.exe stop usosvc",0,True)
            shell.regwrite usosvc_reg & "\WOW64",&H14c,"REG_DWORD"
            msgbox "已禁止Win10自动更新!",vbexclamation
            Exit Do
        Case "2"
            shell.regdelete usosvc_reg & "\WOW64"
            retnum = shell.run("sc.exe start usosvc",0,True)
            msgbox "已恢复Win10自动更新!",vbexclamation
            Exit Do
        Case ""
            Exit Do
        Case Else
            msgbox "输入错误!请重新输入!",vbcritical
        End Select
    Loop
End Sub

将上述代码复制到文本编辑器中，因为是中文界面，所以以 GB2312 或 UTF-16 编码保存，并将文件后缀设置为vbs格式，然后双击运行该程序即可。

上图为该程序可视化界面，默认为1，直接点击确定即可。

出现这个提示，就说明已经禁止 Windows 10 自动更新功能了，有网友反馈在 Windows 11 系统上仍旧可用。